quote do generates wrong type for set[char]

[zevv]

I'm having problems passing set[char] through quote do blocks. The generated literal loses its charness, resulting in a set[uint16] instead.

The following snippet prints {97, 98} instead of {'a', 'b'}:

import macros

proc foo(): bool =   
  var s = { 'a', 'b' }
  var n = quote do:      
    `s`                 
  echo n.repr
const a = foo()

[zevv]

Bad example above, this shows it better:

import macros

macro foo(): untyped =
  var s = { 'a', 'b' }
  quote do:              
    let t = `s`         
    echo typeof(t)

foo()

Results in:

set[range 0..65535(int)]

[krux02]

You forgot to use newLit.

import macros

macro foo(): untyped =
  var s = newLit({ 'a', 'b' })
  quote do:
    let t = `s`
    echo typeof(t)

foo()

The new quoteAst will report an error if you don't appliy newLit properly.

[zevv]

Quoting Arne Döring (2019-08-20 20:36:44)

You forgot to use newLit.

Aaarg, *again*! Can't we make this mandatory somehow?

…

-- :wq ^X^Cy^K^X^C^C^C^C

[krux02]

Aaarg, again! Can't we make this mandatory somehow?

Yes. That is one of the requirements of the new quoteAst

[timotheecour]

I added a test for both of your examples in #11722, which is another proposal to replace quote do

unlike #11823, you don't need to add an intermediate variable newLit in the macro before passing to quoteAst, all it needs is replace

quote do: some code with `foo`

by

genAst(foo):  some code with foo

block: # fix https://github.com/nim-lang/Nim/issues/11986
  proc foo(): auto =
    var s = { 'a', 'b' }
    var n = genAst(s): s
    n.repr
  static: doAssert foo() == "{'a', 'b'}"

block: # also from #11986
  macro foo(): untyped =
    var s = { 'a', 'b' }
    genAst(s):
      let t = s
      $typeof(t)
  doAssert foo() == "set[char]"