[Macro] cannot pass a distinct type to newLit

[nitely]

Cannot pass a distinct type to newLit. Using the values directly seems to work in my case, but the docs/tutorial say to convert them to NimNode using newLit.

Example

import macros

type
  Rune = distinct int32
  Foo = object
    a: Rune

macro foo*(): untyped =
  result = newStmtList()
  let runeLit = newLit Rune(0)
  let fooLit = newLit Foo(a: Rune(0))
  result.add(quote do:
    echo `runeLit`)
  result.add(quote do:
    echo `fooLit`.a)

proc main() =
  foo()
main()

Current Output

Error: type mismatch: got <Rune>

Expected Output

0
0

$ nim -v
Nim Compiler Version 1.1.1 [Linux: amd64]
Compiled at 2020-01-24
Copyright (c) 2006-2019 by Andreas Rumpf

active boot switches: -d:release

[cooldome]

Here is how you do it. You need latest devel nim, because of distinctBase

import macros

type
  Rune = distinct int32
  Foo = object
    a: Rune


proc `$`(r: Rune): string {.borrow.}

import typetraits
proc newLit*(d: distinct): NimNode =
  nnkCall.newTree(typeof(d).getTypeInst, 
            newLit(distinctBase(typeof(d))(d)))

macro foo*(): untyped =
  result = newStmtList()
  let runeLit = newLit Rune(0)
  let fooLit = newLit Foo(a: Rune(0))
  result.add(quote do:
    echo `runeLit`)
  result.add(quote do:
    echo `fooLit`.a)

proc main() =
  foo()
main()

[andreaferretti]

Wouldn't it be better to have this overload of newLit directly in macros?

[krux02]

@andreaferretti I did exactly that in my PR (linked above).