wpaperd: add systemd service; move to services/ from programs/

modules/misc/news.nix

@@ -1919,6 +1919,17 @@ in {
           Cavalier is a GUI wrapper around the Cava audio visualizer.
         '';
       }
+
+      {
+        time = "2024-12-31T06:44:46+00:00";
+        condition = hostPlatform.isLinux;
+        message = ''
+          A new module is available: 'services.wpaperd'.
+
+          This replaces the existing module, 'programs.wpaperd', and adds a
+          systemd service to ensure its execution.
+        '';
+      }
     ];
   };
 }

modules/modules.nix

@@ -261,7 +261,6 @@ let
     ./programs/wezterm.nix
     ./programs/wlogout.nix
     ./programs/wofi.nix
-    ./programs/wpaperd.nix
     ./programs/xmobar.nix
     ./programs/xplr.nix
     ./programs/yambar.nix
@@ -407,6 +406,7 @@ let
     ./services/window-managers/xmonad.nix
     ./services/wlsunset.nix
     ./services/wob.nix
+    ./services/wpaperd.nix
     ./services/xcape.nix
     ./services/xembed-sni-proxy.nix
     ./services/xidlehook.nix

modules/services/wpaperd.nix

@@ -0,0 +1,85 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+  cfg = config.services.wpaperd;
+  tomlFormat = pkgs.formats.toml { };
+in {
+  meta.maintainers = [ hm.maintainers.Avimitin ];
+
+  imports = [
+    (mkRenamedOptionModule # \
+      [ "programs" "wpaperd" "enable" ] # \
+      [ "services" "wpaperd" "enable" ])
+    (mkRenamedOptionModule # \
+      [ "programs" "wpaperd" "package" ] # \
+      [ "services" "wpaperd" "package" ])
+    (mkRenamedOptionModule # \
+      [ "programs" "wpaperd" "settings" ] # \
+      [ "services" "wpaperd" "settings" ])
+  ];
+
+  options.services.wpaperd = {
+    enable = mkEnableOption "wpaperd";
+
+    package = mkPackageOption pkgs "wpaperd" { };
+
+    settings = mkOption {
+      type = tomlFormat.type;
+      default = { };
+      example = literalExpression ''
+        {
+          eDP-1 = {
+            path = "/home/foo/Pictures/Wallpaper";
+            apply-shadow = true;
+          };
+          DP-2 = {
+            path = "/home/foo/Pictures/Anime";
+            sorting = "descending";
+          };
+        }
+      '';
+      description = ''
+        Configuration written to
+        {file}`$XDG_CONFIG_HOME/wpaperd/wallpaper.toml`.
+        See <https://github.com/danyspin97/wpaperd#wallpaper-configuration>
+        for the full list of options.
+      '';
+    };
+  };
+
+  config = mkIf cfg.enable {
+    assertions = [
+      (lib.hm.assertions.assertPlatform "services.wpaperd" pkgs
+        lib.platforms.linux)
+    ];
+
+    home.packages = [ cfg.package ];
+
+    xdg.configFile = {
+      "wpaperd/wallpaper.toml" = mkIf (cfg.settings != { }) {
+        source = tomlFormat.generate "wpaperd-wallpaper" cfg.settings;
+      };
+    };
+
+    systemd.user.services.wpaperd = {
+      Install = { WantedBy = [ "graphical-session.target" ]; };
+
+      Unit = {
+        ConditionEnvironment = "WAYLAND_DISPLAY";
+        Description = "wpaperd";
+        After = [ "graphical-session-pre.target" ];
+        PartOf = [ "graphical-session.target" ];
+        X-Restart-Triggers =
+          [ "${config.xdg.configFile."wpaperd/wallpaper.toml".source}" ];
+      };
+
+      Service = {
+        ExecStart = "${getExe cfg.package}";
+        Restart = "always";
+        RestartSec = "10";
+      };
+    };
+  };
+}

tests/default.nix

@@ -230,7 +230,6 @@ in import nmtSrc {
     ./modules/programs/waybar
     ./modules/programs/wlogout
     ./modules/programs/wofi
-    ./modules/programs/wpaperd
     ./modules/programs/xmobar
     ./modules/programs/yambar
     ./modules/programs/yt-dlp
@@ -303,6 +302,7 @@ in import nmtSrc {
     ./modules/services/window-managers/sway
     ./modules/services/wlsunset
     ./modules/services/wob
+    ./modules/services/wpaperd
     ./modules/services/xsettingsd
     ./modules/systemd
     ./modules/targets-linux

tests/modules/programs/wpaperd/wpaperd-example-settings.nix → tests/modules/services/wpaperd/wpaperd-example-settings.nix

@@ -2,7 +2,7 @@
 
 {
   config = {
-    programs.wpaperd = {
+    services.wpaperd = {
       enable = true;
       settings = {
         eDP-1 = {