Examples

Static tweaks

Add new item with vendor stock (template)

r6/tweaks/MyGlasses.yaml

Items.MyGlasses_01:
  $base: Items.GenericFaceClothing
  entityName: my_glasses_001
  appearanceName: my_glasses_001_
  displayName: My-Glasses-01-Name
  localizedDescription: My-Glasses-01-Desc
  icon:
    atlasResourcePath: mod\my_glasses_001.inkatlas
    atlasPartName: icon_glasses_01

Vendors.wat_lch_clothingshop_01:
  itemStock:
    - !append
      item: Items.MyGlasses_01
      quantity: [ Vendors.Always_Present ]

Make sniper and rifle scopes attachable to handguns

r6/tweaks/HandgunScopes.yaml

Items.HandgunPossibleScopesList:
  itemPartList:
    - !append-from Items.RiflePossibleScopesList.itemPartList
    - !append-from Items.SniperPossibleScopesList.itemPartList

Make police vehicles savable in player's garage

r6/tweaks/PlayerPoliceCars.yaml

Vehicle.vehicle_list.list:
  - !append-once Vehicle.v_standard2_archer_hella_police
  - !append-once Vehicle.v_standard2_villefort_cortes_police
  - !append-once Vehicle.v_standard3_chevalier_emperor_police

Allow more spawns for Prevention System

r6/tweaks/PreventionSystemSpawns.yaml

PreventionSystem.setup.totalEntitiesLimit: 40
PreventionSystem.vehicle_spawn_setup.vehicleDespawnDistance: 75.0

Scriptable tweaks

Remove cyberware equip requirements

r6/scripts/NoCyberwareEquipReqs.reds

public class NoCyberwareEquipReqs extends ScriptableTweak {
  protected cb func OnApply() -> Void {
    // Enumerate all item records
    for record in TweakDBInterface.GetRecords(n"Item") {
      let item = record as Item_Record;

      // Filter out only cyberware items
      if item.ItemType().GetID() == t"ItemType.Cyberware" {

        // Get all equip requirements for the item
        let prereqs: array<wref<IPrereq_Record>>;
        item.EquipPrereqs(prereqs);

        // Reset every required level to zero
        for prereq in prereqs {
          TweakDBManager.SetFlat(prereq.GetID() + t".valueToCheck", 0.0);
          TweakDBManager.UpdateRecord(prereq.GetID());
        }
      }
    }
  }
}