Entry BOOT-INF/lib/jaxb-core-4.0.1.jar is a duplicate but no duplicate handling strategy has been set

[naihil]

Simple gradle Spring Boot 3 project with Spring Data and Spring Web Services:

build.gradle:

plugins {
	  id 'java'
	  id 'org.springframework.boot' version '3.0.1'
	  id 'io.spring.dependency-management' version '1.1.0'
}

group = 'com.ws'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '17'

repositories {
	mavenCentral()
}

dependencies {
	implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
	implementation 'org.springframework.boot:spring-boot-starter-web-services'

	testImplementation 'org.springframework.boot:spring-boot-starter-test'
}
  
tasks.named('test') {
	useJUnitPlatform()
}

Error:

Execution failed for task ':bootJar'.
> Entry BOOT-INF/lib/jaxb-core-4.0.1.jar is a duplicate but no duplicate handling strategy has been set. Please refer to https://docs.gradle.org/7.6/dsl/org.gradle.api.tasks.Copy.html#org.gradle.api.tasks.Copy:duplicatesStrategy for details.

[HououinKyouma2000]

org.hibernate:hibernate-envers:6 .
i have the same problem. In the course of the conflict in the libraries inside. Below is one of the possible solutions, but it is not the best.
Write it in gradle
bootJar.enabled = false

[naihil]

Another workaround:

tasks.named('bootJar') {
duplicatesStrategy = DuplicatesStrategy.EXCLUDE
}

[bclozel]

@HououinKyouma2000 Disabling boot repackaging will prevent the application from runnning as an executable jar and won't solve the underlying problem.

@naihil I'm not sure excluding the dependency will solve the issue here, as excluding duplicates will exclude one of the jaxb-core jars: in this case, they're holding different content with classes located under different packages. This could lead to missing classes at runtime.

It looks like spring-ws-core has a hard dependency on com.sun.xml.bind:jaxb-core:

./gradlew dependencyInsight --dependency jaxb-core --configuration runtimeClasspath

> Task :dependencyInsight
com.sun.xml.bind:jaxb-core:4.0.1 (selected by rule)
  Variant runtime:
    | Attribute Name                 | Provided     | Requested    |
    |--------------------------------|--------------|--------------|
    | org.gradle.status              | release      |              |
    | org.gradle.category            | library      | library      |
    | org.gradle.libraryelements     | jar          | jar          |
    | org.gradle.usage               | java-runtime | java-runtime |
    | org.gradle.dependency.bundling |              | external     |
    | org.gradle.jvm.environment     |              | standard-jvm |
    | org.gradle.jvm.version         |              | 17           |

com.sun.xml.bind:jaxb-core:4.0.1
\--- com.sun.xml.bind:jaxb-impl:4.0.1
     \--- org.springframework.ws:spring-ws-core:4.0.0 (requested com.sun.xml.bind:jaxb-impl:4.0.0)
          \--- org.springframework.boot:spring-boot-starter-web-services:3.0.1
               \--- runtimeClasspath (requested org.springframework.boot:spring-boot-starter-web-services)

org.glassfish.jaxb:jaxb-core:4.0.1 (selected by rule)
  Variant runtime:
    | Attribute Name                 | Provided     | Requested    |
    |--------------------------------|--------------|--------------|
    | org.gradle.status              | release      |              |
    | org.gradle.category            | library      | library      |
    | org.gradle.libraryelements     | jar          | jar          |
    | org.gradle.usage               | java-runtime | java-runtime |
    | org.gradle.dependency.bundling |              | external     |
    | org.gradle.jvm.environment     |              | standard-jvm |
    | org.gradle.jvm.version         |              | 17           |

org.glassfish.jaxb:jaxb-core:4.0.1
\--- org.glassfish.jaxb:jaxb-runtime:4.0.1
     \--- org.hibernate.orm:hibernate-core:6.1.6.Final (requested org.glassfish.jaxb:jaxb-runtime:3.0.2)
          \--- org.springframework.boot:spring-boot-starter-data-jpa:3.0.1
               \--- runtimeClasspath (requested org.springframework.boot:spring-boot-starter-data-jpa)

Spring Boot has been using the Glassfish RI for a while now, so I'm wondering if this is an oversight or even needed in spring-ws?

Does the following work for your applications @naihil ?

dependencies {
	implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
	implementation ('org.springframework.boot:spring-boot-starter-web-services') {
		exclude group: "com.sun.xml.bind"
	}

	testImplementation 'org.springframework.boot:spring-boot-starter-test'
}

[naihil]

implementation ('org.springframework.boot:spring-boot-starter-web-services') {
exclude group: "com.sun.xml.bind"
}

Checked this variant, application builds and tests fine, fat jar contains jaxb-core-4.0.1.jar and jaxb-runtime-4.0.1.jar

Variant with DuplicatesStrategy.EXCLUDE compiles and tests fine too, but fat jar contains jaxb-core-4.0.1.jar, jaxb-runtime-4.0.1.jar and jaxb-impl-4.0.1.jar

[naihil]

Oops, close accidentally, reopen.

[anbusampath]

Spring Boot has been using the Glassfish RI for a while now, so I'm wondering if this is an oversight or even needed in spring-ws?

spring-ws can migrate to org.glassfish.jaxb:jaxb-runtime from com.sun.xml.bind:jaxb-impl, as both contain same classes only differs with packing style. https://eclipse-ee4j.github.io/jaxb-ri/4.0.1/docs/release-documentation.html#deployment-maven-coordinates

but fat jar contains jaxb-core-4.0.1.jar, jaxb-runtime-4.0.1.jar and jaxb-impl-4.0.1.jar

In contrast to org.glassfish.jaxb artifacts, these(com.sun.xml.bind:jaxb-impl) jars have all dependency classes included inside.

[bclozel]

We've discussed this as a team and we've created a Spring WS issue to address this problem. See spring-projects/spring-ws#1305