build.gradle

import org.codehaus.groovy.runtime.GStringImpl

plugins {
    id 'idea'
    id 'distribution'
}

apply plugin: 'application'
apply plugin: 'scala'

repositories {
    mavenCentral()
}

ext {
    scalaStyleConfig = "$rootDir/scalastyle_config.xml"
}

subprojects { subproject ->
    group 'de.thm.ii'
    version '1.0-SNAPSHOT'
}

task dist(dependsOn: ["fbs-runner.checker:installDist", "distApi", "distWeb"]) {}

task distApi(dependsOn: ['fbs-core.api:installDist']) {}
task distWeb(dependsOn: ["fbs-core.web:installDist", "fbs-core.web:copyWebToWS"])
distApi.shouldRunAfter distWeb

distributions {
    main {
        distributionBaseName = project.name
        contents {
            project.subprojects.each { sub ->
                switch (sub.name) {
                    case 'fbs-core.web':
                        into('modules/fbs-core/api/http') {
                            from "${sub.buildDir}/install/${sub.name}"
                            include '*/**'
                        }
                        break
                    case 'fbs-core.api':
                        into('') {
                            from "${sub.buildDir}/install/"
                            include '*/**'
                        }
                        into(sub.name) {
                            from "${sub.projectDir}"
                            include 'Dockerfile'
                        }
                        break
                }
            }
        }
    }
}

task jacocoRootReport() {
    dependsOn = ['fbs-core.api:jacocoReport', 'fbs-runner.checker:jacocoReport']
}

dependencies {
    compileOnly 'org.scala-lang:scala-library:2.13.1'
}