std: update std.builtin.Type fields to follow naming conventions

[mlugg]

What can I say? I just felt like breaking everyone's code this release cycle.

This is a prerequisite for a minor language change (disallowing fields and declarations with the same name) which is itself a prerequisite of #9938.

[SeanTheGleaming]

Probably for the best. This had been bugging me forever!

[mlugg]

@andrewrk I'm confident that the changes are correct, but idk if you want to look this over anyway. Perhaps just double-check that the field names in Type are what you expected (e.g. I've used .noreturn even though a "direct" rewrite of the old tag name would be .no_return)

[andrewrk]

Looks good. It makes sense for result of reflection to use the same names as the types.

[mlugg]

Release Notes

std.builtin.Type Fields Renamed

In most cases, Zig's standard library follows the naming conventions given [in the language reference](https://ziglang.org/documentation/0.14.0/#toc-Names\). Zig 0.14.0 updates the fields of the std.builtin.Type tagged union to follow these conventions by lowercasing them:

pub const Type = union(enum) {
    type: void,
    void: void,
    bool: void,
    noreturn: void,
    int: Int,
    float: Float,
    pointer: Pointer,
    array: Array,
    @"struct": Struct,
    comptime_float: void,
    comptime_int: void,
    undefined: void,
    null: void,
    optional: Optional,
    error_union: ErrorUnion,
    error_set: ErrorSet,
    @"enum": Enum,
    @"union": Union,
    @"fn": Fn,
    @"opaque": Opaque,
    frame: Frame,
    @"anyframe": AnyFrame,
    vector: Vector,
    enum_literal: void,
    // ...
};

Note that this requires using "quoted identifier" syntax for @"struct", @"union", @"enum", @"opaque", and @"anyframe", because these identifiers are also keywords.

This change is widely breaking, but upgrading is simple:

test "switch on type info" {
    const x = switch (@typeInfo(u8)) {
        .Int => 0,
        .ComptimeInt => 1,
        .Struct => 2,
        else => 3,
    };
    try std.testing.expect(0, x);
}
test "reify type" {
    const U8 = @Type(.{ .Int = .{
        .signedness = .unsigned,
        .bits = 8,
    } });
    const S = @Type(.{ .Struct = .{
        .layout = .auto,
        .fields = &.{},
        .decls = &.{},
        .is_tuple = false,
    } });
    try std.testing.expect(U8 == u8);
    try std.testing.expect(@typeInfo(S) == .Struct);
}
const std = @import("std");

-->

test "switch on type info" {
    const x = switch (@typeInfo(u8)) {
        .int => 0,
        .comptime_int => 1,
        .@"struct" => 2,
        else => 3,
    };
    try std.testing.expect(0, x);
}
test "reify type" {
    const U8 = @Type(.{ .int = .{
        .signedness = .unsigned,
        .bits = 8,
    } });
    const S = @Type(.{ .@"struct" = .{
        .layout = .auto,
        .fields = &.{},
        .decls = &.{},
        .is_tuple = false,
    } });
    try std.testing.expect(U8 == u8);
    try std.testing.expect(@typeInfo(S) == .@"struct");
}
const std = @import("std");