Add third automatic loot option for food and drinks, to have them be consumed immediately

DXRFixes/DeusEx/Classes/Carcass.uc

@@ -257,11 +257,13 @@ function Frob(Actor Frobber, Inventory frobWith)
 function bool TryLootItem(DeusExPlayer player, Inventory item)
 {
     local DeusExPickup invItem;
-    local int itemCount, newAmmoAmmout, ammoAddedAmount;
+    local int itemCount, newAmmoAmmout, ammoAddedAmount, action;
     local Weapon weap;
     local Ammo playerAmmo;
 
-    if (class'DXRLoadouts'.static.IsRefused(item.class)) {
+    action = class'DXRLoadouts'.static.GetLootAction(item.class);
+
+    if (action == 1) { // drop
         weap = Weapon(item);
         if (weap != None && weap.AmmoName != class'AmmoNone') {
             playerAmmo = Ammo(player.FindInventoryType(weap.AmmoName));
@@ -281,6 +283,13 @@ function bool TryLootItem(DeusExPlayer player, Inventory item)
         return true;
     }
 
+    if (action == 2 && Human(player).ConsumableWouldHelp(item) && DeusExPickup(item) != None) { // consume
+        DeleteInventory(item);
+        DeusExRootWindow(player.rootWindow).hud.receivedItems.AddItem(item, 1);
+        Human(player).InstantlyUseItem(DeusExPickup(item));
+        return true;
+    }
+
     if (item.IsA('NanoKey'))
     {
         player.PickupNanoKey(NanoKey(item));

DXRModules/DeusEx/Classes/DXRLoadouts.uc

@@ -478,10 +478,11 @@ simulated function PlayerLogin(#var(PlayerPawn) p)
 
     RandoStartingEquipment(p, false);
 #ifdef injections
-    class'MenuChoice_RefuseUseless'.static.SetRefusals();
-    class'MenuChoice_RefuseFoodDrink'.static.SetRefusals();
-    class'MenuChoice_RefuseMelee'.static.SetRefusals();
-    class'MenuChoice_RefuseMisc'.static.SetRefusals();
+    class'MenuChoice_LootActionUseless'.static.SetActions();
+    class'MenuChoice_LootActionFoodSoda'.static.SetActions();
+    class'MenuChoice_LootActionAlcohol'.static.SetActions();
+    class'MenuChoice_LootActionMelee'.static.SetActions();
+    class'MenuChoice_LootActionMisc'.static.SetActions();
 #endif
 }
 
@@ -696,53 +697,45 @@ function SpawnItems()
         reducer.Timer();
 }
 
-static function bool IsRefused(class<Inventory> type, optional out int strIdx)
-{
-    local DataStorage datastorage;
-    local string refusals;
-
-    datastorage = class'DataStorage'.static.GetObj(class'DXRando'.default.dxr);
-    refusals = datastorage.GetConfigKey("item_refusals");
-    if(refusals == "") {
-        return false;
+static function int GetLootAction(
+    class<Inventory> itemClass,
+    optional DataStorage storage,
+    optional out string lootActions,
+    optional out int strIdx
+) {
+    if (storage == None)
+        storage = class'DataStorage'.static.GetObj(class'DXRando'.default.dxr);
+
+    lootActions = storage.GetConfigKey("loot_actions");
+    strIdx = InStr(lootActions, "," $ itemClass.name $ "=");
+    if (strIdx != -1) {
+        return Int(Mid(lootActions, strIdx + Len(itemClass.name) + 2, 1));
     }
-    strIdx = InStr(refusals, "," $ type.name $ ",");
-    return strIdx != -1;
+    return 0;
 }
 
-static function UnsetRefuseItem(class<Inventory> type)
+static function SetLootAction(class<Inventory> itemClass, int action, optional DataStorage storage)
 {
-    local DataStorage datastorage;
-    local string refusals, leftPart, rightPart;
+    local string lootActions, leftPart, rightPart;
     local int strIdx;
 
-    if (!IsRefused(type, strIdx))
-        return;
-
-    datastorage = class'DataStorage'.static.GetObj(class'DXRando'.default.dxr);
-    refusals = datastorage.GetConfigKey("item_refusals");
-    leftPart = Left(refusals, strIdx);
-    rightPart = Right(refusals, Len(refusals) - (strIdx + Len(type.name) + 1));
-    refusals = leftPart $ rightPart;
-
-    datastorage.SetConfig("item_refusals", refusals, 3600*24*366);
-}
-
-static function SetRefuseItem(class<Inventory> type)
-{
-    local DataStorage datastorage;
-    local string refusals;
-
-    if (IsRefused(type))
+    if (storage == None) {
+        storage = class'DataStorage'.static.GetObj(class'DXRando'.default.dxr);
+    }
+    if (GetLootAction(itemClass, storage, lootActions, strIdx) == action) {
         return;
+    }
 
-    datastorage = class'DataStorage'.static.GetObj(class'DXRando'.default.dxr);
-    refusals = datastorage.GetConfigKey("item_refusals");
-
-    if (refusals == "") refusals = ",";
-    refusals = refusals $ type.name $ ",";
-
-    datastorage.SetConfig("item_refusals", refusals, 3600*24*366);
+    if (lootActions == "") {
+        lootActions = "," $ itemClass.name $ "=" $ action $ ",";
+    } else if (strIdx == -1) {
+        lootActions = lootActions $ itemClass.name $ "=" $ action $ ",";
+    } else {
+        leftPart = Left(lootActions, strIdx + Len(itemClass.name) + 2);
+        rightPart = Mid(lootActions, strIdx + Len(itemClass.name) + 3);
+        lootActions = leftPart $ action $ rightPart;
+    }
+    storage.SetConfig("loot_actions", lootActions, 3600*24*366);
 }
 
 function RunTests()

DXRVanilla/DeusEx/Classes/PersonaScreenInventory.uc

@@ -179,10 +179,17 @@ function EnableButtons()
         inv = Inventory(selectedItem.GetClientObject());
 
         if (inv != None) {
-            if (class'DXRLoadouts'.static.IsRefused(inv.class)) {
-                btnRefusal.SetButtonText(AcceptLabel);
-            } else {
-                btnRefusal.SetButtonText(RefuseLabel);
+            switch (class'DXRLoadouts'.static.GetLootAction(inv.class)) {
+                case 0:
+                    btnRefusal.SetButtonText(RefuseLabel);
+                    break;
+                case 1:
+                    btnRefusal.SetButtonText(AcceptLabel);
+                    break;
+                case 2:
+                    btnRefusal.SetButtonText(RefuseLabel);
+                    btnRefusal.DisableWindow();
+                    break;
             }
 
             if (NanoKeyRing(inv) != None) {
@@ -240,9 +247,9 @@ function UnsetRefuseItem()
     local Inventory item;
 
     item = Inventory(selectedItem.GetClientObject());
-    if(item == None) return;
+    if (item == None) return;
 
-    class'DXRLoadouts'.static.UnsetRefuseItem(item.class);
+    class'DXRLoadouts'.static.SetLootAction(item.class, 0);
     btnRefusal.SetButtonText(RefuseLabel);
     player.ClientMessage(item.ItemName $ " set as not trash.");
 }
@@ -254,9 +261,9 @@ function SetRefuseItem()
     local Vector dropVect;
 
     item = Inventory(selectedItem.GetClientObject());
-    if(item == None) return;
+    if (item == None) return;
 
-    class'DXRLoadouts'.static.SetRefuseItem(item.class);
+    class'DXRLoadouts'.static.SetLootAction(item.class, 1);
 
     if (Pickup(item) == None) {
         DropSelectedItem();

DXRVanilla/DeusEx/Classes/Player.uc

@@ -532,34 +532,42 @@ function bool CanInstantLeftClick(DeusExPickup item)
 exec function ParseLeftClick()
 {
     local DeusExPickup item;
-    local Actor A;
-    local int i;
 
     Super.ParseLeftClick();
     item = DeusExPickup(FrobTarget);
     if (item != None && CanInstantLeftClick(item))
     {
-        foreach item.BasedActors(class'Actor', A)
-            A.SetBase(None);
-        // So that any effects get applied to you
-        item.SetOwner(self);
-        item.SetBase(self);
-        // add to the player's inventory, so ChargedPickups travel across maps
-        item.BecomeItem();
-        item.bDisplayableInv = false;
-        item.Inventory = Inventory;
-        Inventory = item;
-        if(FireExtinguisher(item) != None) {
-            // this was buggy with multiple, but it doesn't make sense and wouldn't be useful to use multiple at once anyways
-            item.NumCopies = 1;
-        }
-        for(i=item.NumCopies; i > 0; i--) {
-            item.Activate();
-        }
+        InstantlyUseItem(item);
         FrobTarget = None;
     }
 }
 
+function InstantlyUseItem(DeusExPickup item)
+{
+    local Actor A;
+    local int i;
+
+    if(item == None) return;
+
+    foreach item.BasedActors(class'Actor', A)
+        A.SetBase(None);
+    // So that any effects get applied to you
+    item.SetOwner(self);
+    item.SetBase(self);
+    // add to the player's inventory, so ChargedPickups travel across maps
+    item.BecomeItem();
+    item.bDisplayableInv = false;
+    item.Inventory = Inventory;
+    Inventory = item;
+    if(FireExtinguisher(item) != None) {
+        // this was buggy with multiple, but it doesn't make sense and wouldn't be useful to use multiple at once anyways
+        item.NumCopies = 1;
+    }
+    for(i=item.NumCopies; i > 0; i--) {
+        item.Activate();
+    }
+}
+
 exec function ParseRightClick()
 {
     local bool handled;
@@ -1682,23 +1690,45 @@ exec function PlayerRot()
     ClientMessage("Player rotation: (" $ Rotation.pitch $ ", " $ Rotation.yaw $ ", " $ Rotation.roll $ ")");
 }
 
-exec function ShowRefused()
+exec function LootActions()
 {
-    local string refusals, msg;
+    local string lootActions, msg;
     local int idx;
 
-    refusals = class'DataStorage'.static.GetObj(GetDXR()).GetConfigKey("item_refusals");
+    lootActions = class'DataStorage'.static.GetObj(GetDXR()).GetConfigKey("loot_actions");
 
     // basically just adds a space after every comma
-    while (Len(refusals) > 1) {
-        refusals = Right(refusals, Len(refusals) - 1);
-        idx = InStr(refusals, ",");
-        msg = msg $ Left(refusals, idx) $ ", ";
-        refusals = Right(refusals, Len(refusals) - idx);
+    lootActions = Mid(lootActions, 1);
+    while (lootActions != "") {
+        idx = InStr(lootActions, ",");
+        msg = msg $ Left(lootActions, idx) $ ", ";
+        lootActions = Mid(lootActions, idx + 1);
     }
     msg = Left(msg, Len(msg) - 2);
 
-    ClientMessage("Refused items: " $ msg);
+    ClientMessage("Loot actions: " $ msg);
+}
+
+function bool ConsumableWouldHelp(Inventory item) {
+    if (health < default.health) {
+        if (MedKit(item) != None || SoyFood(item) != None || Candybar(item) != None || Sodacan(item) != None) {
+            return true;
+        }
+        if (HealingItem(item) != None && HealingItem(item).health > 0) {
+            return true;
+        }
+    }
+
+    if (energy < default.energy) {
+        if (BioElectricCell(item) != None) {
+            return true;
+        }
+        if (HealingItem(item) != None && HealingItem(item).energy > 0) {
+            return true;
+        }
+    }
+
+    return false;
 }
 
 

GUI/DeusEx/Classes/MenuChoice_LootAction.uc

@@ -0,0 +1,33 @@
+class MenuChoice_LootAction extends DXRMenuUIChoiceInt;
+#compileif injections
+
+var class<Inventory> itemClasses[5];
+
+static function SetActions()
+{
+    local class<Inventory> itemClass;
+    local DataStorage storage;
+    local int i;
+
+    storage = class'DataStorage'.static.GetObj(class'DXRando'.default.dxr);
+    for (i = 0; i < ArrayCount(default.itemClasses); i++) {
+        itemClass = default.itemClasses[i];
+        if (itemClass == None)
+            continue;
+        class'DXRLoadouts'.static.SetLootAction(itemClass, default.value, storage);
+    }
+}
+
+function SaveSetting()
+{
+    Super.SaveSetting();
+    SetActions();
+}
+
+defaultproperties
+{
+    value=0
+    defaultvalue=0
+    enumText(0)="Pick Up"
+    enumText(1)="Drop"
+}

GUI/DeusEx/Classes/MenuChoice_LootActionAlcohol.uc

@@ -0,0 +1,13 @@
+class MenuChoice_LootActionAlcohol extends MenuChoice_LootAction;
+#compileif injections
+
+defaultproperties
+{
+    HelpText="Should alcohol be included in the list of Junk items that get dropped when looting a body, or get consumed automatically?"
+    actionText="Alcohol"
+
+    itemClasses(0)=class'Liquor40oz'
+    itemClasses(1)=class'LiquorBottle'
+    itemClasses(2)=class'WineBottle'
+    enumText(2)="Consume"
+}

GUI/DeusEx/Classes/MenuChoice_LootActionFoodSoda.uc

@@ -0,0 +1,13 @@
+class MenuChoice_LootActionFoodSoda extends MenuChoice_LootAction;
+#compileif injections
+
+defaultproperties
+{
+    HelpText="Should food and soda be included in the list of Junk items that get dropped when looting a body, or get consumed automatically?"
+    actionText="Food and Soda"
+
+    itemClasses(0)=class'SoyFood'
+    itemClasses(1)=class'Candybar'
+    itemClasses(2)=class'Sodacan'
+    enumText(2)="Consume"
+}

GUI/DeusEx/Classes/MenuChoice_LootActionMelee.uc

@@ -0,0 +1,16 @@
+class MenuChoice_LootActionMelee extends MenuChoice_LootAction;
+#compileif injections
+
+defaultproperties
+{
+    value=1
+    defaultvalue=1
+    HelpText="Should melee weapons be included in the list of Junk items that get dropped when looting a body?"
+    actionText="Melee Weapons"
+
+    itemClasses(0)=class'WeaponCombatKnife'
+    itemClasses(1)=class'WeaponCrowbar'
+    itemClasses(2)=class'WeaponSword'
+    itemClasses(3)=class'WeaponNanoSword'
+    itemClasses(4)=class'WeaponBaton'
+}