Integrate Apollo

addons/apollo/$PBOPREFIX$

@@ -0,0 +1 @@
+x\tac\addons\apollo

addons/apollo/ACE_Settings.hpp

@@ -0,0 +1,20 @@
+class ACE_Settings {
+    class GVAR(enabled) {
+        value = 0;
+        typeName = "BOOL";
+        displayName = "$STR_ACE_Common_Enabled";
+        description = CSTRING(EnabledDesc);
+    };
+    class GVAR(enabledPlayers) {
+        value = 1;
+        typeName = "BOOL";
+        displayName = CSTRING(EnabledPlayers);
+        description = CSTRING(EnabledPlayersDesc);
+    };
+    class GVAR(enabledVehicles) {
+        value = 1;
+        typeName = "BOOL";
+        displayName = CSTRING(EnabledVehicles);
+        description = CSTRING(EnabledVehiclesDesc);
+    };
+};

addons/apollo/CfgEventHandlers.hpp

@@ -0,0 +1,34 @@
+class Extended_PreStart_EventHandlers {
+    class ADDON {
+        init = QUOTE(call COMPILE_FILE(XEH_preStart));
+    };
+};
+
+class Extended_PreInit_EventHandlers {
+    class ADDON {
+        init = QUOTE(call COMPILE_FILE(XEH_preInit));
+    };
+};
+
+class Extended_PostInit_EventHandlers {
+    class ADDON {
+        clientInit = QUOTE(call COMPILE_FILE(XEH_postInitClient));
+        serverInit = QUOTE(call COMPILE_FILE(XEH_postInitServer));
+    };
+};
+
+class Extended_Killed_EventHandlers {
+    class CAManBase {
+        class ADDON {
+            killed = QUOTE(_this call FUNC(handleKilled));
+        };
+    };
+};
+
+class Extended_Respawn_EventHandlers {
+    class CAManBase {
+        class ADDON {
+            respawn = QUOTE(_this call FUNC(handleRespawn));
+        };
+    };
+};

addons/apollo/CfgVehicles.hpp

@@ -0,0 +1,37 @@
+class CfgVehicles {
+    class ACE_Module;
+    class GVAR(module): ACE_Module {
+        author = ECSTRING(main,Author);
+        category = "TAC";
+        displayName = CSTRING(Module);
+        function = QFUNC(moduleInit);
+        scope = 2;
+        isGlobal = 1; // Global
+        isTriggerActivated = 0;
+        isDisposable = 0;
+        //icon = QPATHTOF(UI\Icon_Module_Chronos_ca.paa); @todo
+        class Arguments {
+            class enabled {
+                displayName = "$STR_ACE_Common_Enabled";
+                description = CSTRING(EnabledDesc);
+                typeName = "BOOL";
+                defaultValue = 1;
+            };
+            class enabledPlayers {
+                displayName = CSTRING(EnabledPlayers);
+                description = CSTRING(EnabledPlayersDesc);
+                typeName = "BOOL";
+                defaultValue = 1;
+            };
+            class enabledVehicles {
+                displayName = CSTRING(EnabledVehicles);
+                description = CSTRING(EnabledVehiclesDesc);
+                typeName = "BOOL";
+                defaultValue = 1;
+            };
+        };
+        class ModuleDescription {
+            description = CSTRING(ModuleDesc);
+        };
+    };
+};

addons/apollo/README.md

@@ -0,0 +1,7 @@
+# About
+
+Adds Apollo in-game persistence system (part of Chronos).
+
+### Authors
+
+- [Jonpas](https://github.com/jonpas)

addons/apollo/XEH_PREP.hpp

@@ -0,0 +1,15 @@
+PREP(endMissionError);
+PREP(handleConnect);
+PREP(handleDisconnect);
+PREP(handleKilled);
+PREP(handleLoadoutChanged);
+PREP(handleRespawn);
+PREP(invokeJavaMethod);
+PREP(lockerAction);
+PREP(moduleInit);
+PREP(playerLoadClient);
+PREP(playerSingletonSave);
+PREP(vehicleLoad);
+PREP(vehicleSaveServer);
+PREP(vehicleSingletonLoad);
+PREP(vehicleSingletonSave);

addons/apollo/XEH_postInitClient.sqf

@@ -0,0 +1,47 @@
+#include "script_component.hpp"
+
+// Exit on Headless
+if (!hasInterface) exitWith {};
+
+[QGVAR(initialized), {
+    // Check ApolloClient presenece and version
+    private _apolloClientVersion = "ApolloClient" callExtension "version";
+    if (_apolloClientVersion == "") exitWith {
+        ACE_LOGERROR("Failed to initialize - Missing ApolloClient extension!");
+        ["Your connection has been terminated - Missing ApolloClient extension!"] call FUNC(endMissionError);
+    };
+    if (_apolloClientVersion != "1.1") exitWith {
+        ACE_LOGERROR_1("Failed to initialize - Wrong ApolloClient extension version (active: %1 - required: 1.1)!",_apolloClientVersion);
+        [format ["Your connection has been terminated - Wrong ApolloClient extension version (active: %1 - required: 1.1)!", _apolloClientVersion]] call FUNC(endMissionError);
+    };
+
+    // Terminate to lobby EH
+    [QGVAR(terminatePlayer), {
+        ACE_LOGERROR("Connection terminated - Unknown error with Chronos!");
+        ["Your connection has been terminated - Unknown error with Chronos!"] call FUNC(endMissionError);
+    }] call CBA_fnc_addEventHandler;
+
+    // Load player after Respawn EH
+    [QGVAR(reinitializePlayer), {
+        params ["_player", "_registeredDeath"];
+        TRACE_1("Registered Death",_this);
+
+        // Load player
+        if (_registeredDeath == "done") then {
+            if ([_player] call FUNC(playerLoadClient)) then {
+                ACE_LOGINFO("Client respawned successfully.")
+            };
+        } else {
+            ACE_LOGERROR("Connection terminated - Death failed to register!");
+            [localize LSTRING(RespawnReinitialization)] call FUNC(endMissionError);
+        };
+    }] call CBA_fnc_addEventHandler;
+
+    // Load player and exit if loading failed
+    if !([player] call FUNC(playerLoadClient)) exitWith {};
+
+    // Save on each inventory change with at least 10 seconds between each save
+    ["loadout", FUNC(handleLoadoutChanged)] call CBA_fnc_addPlayerEventHandler;
+
+    ACE_LOGINFO("Client loaded successfully.");
+}] call CBA_fnc_addEventHandler;

addons/apollo/XEH_postInitServer.sqf

@@ -0,0 +1,48 @@
+#include "script_component.hpp"
+
+["ace_settingsInitialized", {
+    if (!GVAR(enabled)) exitWith { TRACE_1("Apollo Disabled",GVAR(enabled)) };
+
+    // Check JNI presence
+    if ("jni" callExtension "version" == "") exitWith {
+        ACE_LOGERROR("Failed to initialize - Missing JNI extension!");
+    };
+
+    // Set server type (debug or live) globally
+    private _serverType = ["getServerType"] call FUNC(invokeJavaMethod);
+    GVAR(isDebug) = [false, true] select (_serverType isEqualTo "debug");
+    publicVariable QGVAR(isDebug);
+
+    if (GVAR(enabledVehicles)) then {
+        call FUNC(vehicleLoad);
+    };
+
+    if (GVAR(enabledPlayers)) then {
+        // Save player
+        [QGVAR(savePlayer), {
+            params ["_player", "_type"];
+            [_player, getPlayerUID _player, _type] call FUNC(playerSingletonSave);
+        }] call CBA_fnc_addEventHandler;
+
+        // Player died
+        [QGVAR(playerDied), {
+            params ["_player", "_killerUID"];
+            TRACE_1("Player Died",_this);
+            private _registeredDeath = ["playerDied", getPlayerUID _player, _killerUID] call FUNC(invokeJavaMethod);
+            [QGVAR(reinitializePlayer), [_player, _registeredDeath], _player] call CBA_fnc_targetEvent;
+        }] call CBA_fnc_addEventHandler;
+
+        // Hiding and disabling simulation (has to be executed on server, during init there is lag, so we do it on server directly)
+        ["CAManBase", "InitPost", FUNC(handleConnect), true, [], true] call CBA_fnc_addClassEventHandler;
+
+        // Corpse removal (prevent item multiplication when leaving nicely)
+        addMissionEventHandler ["HandleDisconnect", FUNC(handleDisconnect)];
+
+        // Start client initialization
+        [QGVAR(initialized), []] call CBA_fnc_globalEventJIP;
+    };
+
+    [QGVAR(lockerAction), FUNC(lockerAction)] call CBA_fnc_addEventHandler;
+
+    ACE_LOGINFO_3("Server loaded successfully (Players: %1 - Vehicles: %2 - Debug: %3)",GVAR(enabledPlayers),GVAR(enabledVehicles),GVAR(isDebug));
+}] call CBA_fnc_addEventHandler;

addons/apollo/XEH_preInit.sqf

@@ -0,0 +1,11 @@
+#include "script_component.hpp"
+
+ADDON = false;
+
+#include "XEH_PREP.hpp"
+
+GVAR(vehiclesLoaded) = false;
+GVAR(isDebug) = false;
+GVAR(vehiclesList) = [];
+
+ADDON = true;

addons/apollo/XEH_preStart.sqf

@@ -0,0 +1,3 @@
+#include "script_component.hpp"
+
+#include "XEH_PREP.hpp"

addons/apollo/config.cpp

@@ -0,0 +1,18 @@
+#include "script_component.hpp"
+
+class CfgPatches {
+    class ADDON {
+        units[] = {};
+        weapons[] = {};
+        requiredVersion = REQUIRED_VERSION;
+        requiredAddons[] = {"tac_main"};
+        author = ECSTRING(main,Author);
+        authors[]= {"Jonpas"};
+        url = ECSTRING(main,URL);
+        VERSION_CONFIG;
+    };
+};
+
+#include "ACE_Settings.hpp"
+#include "CfgEventHandlers.hpp"
+#include "CfgVehicles.hpp"

addons/apollo/functions/fnc_endMissionError.sqf

@@ -0,0 +1,26 @@
+/*
+ * Author: Jonpas
+ * Ends mission with error message on client.
+ *
+ * Arguments:
+ * 0: Error Message <STRING>
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * ["Error"] call tac_apollo_fnc_endMissionError
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+params ["_errorMessage"];
+
+titleText ["", "BLACK IN", 0];
+titleText [_errorMessage, "black"];
+titleFadeOut 9999;
+
+[{
+    ["end1", false, 0] call BIS_fnc_endMission;
+}, [], 5] call CBA_fnc_waitAndExecute;

addons/apollo/functions/fnc_handleConnect.sqf

@@ -0,0 +1,43 @@
+/*
+ * Author: Jonpas
+ * Handles unit visibility and simulation on connect during loading.
+ * Restores state if not player, for players state is restored after successfully loading.
+ * isPlayer and getPlayerUID are not guaranteed to be set when this runs, thus wait.
+ *
+ * Arguments:
+ * 0: Unit <OBJECT>
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * [unit] call tac_apollo_fnc_handleConnect
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+params ["_unit"];
+
+_unit enableSimulationGlobal false;
+_unit hideObjectGlobal true;
+TRACE_4("Handle Client Connect",_unit,isObjectHidden _unit,isPlayer _unit,getPlayerUID _unit);
+
+// Exit if already player (when loading in with server client init finishes sooner)
+if (isPlayer _unit) exitWith {
+    TRACE_1("Handle Client Connect - Is Player",_unit);
+};
+
+// Wait until becomes player or 5 seconds, restores state if not player
+[{
+    params ["_unit", "_timeStart"];
+    isPlayer _unit || {_timeStart + 5 < CBA_missionTime}
+}, {
+    params ["_unit"];
+
+    if (!isPlayer _unit) then {
+        _unit enableSimulationGlobal true;
+        _unit hideObjectGlobal false;
+        TRACE_4("Handle Client Connect - Not Player",_unit,isObjectHidden _unit,isPlayer _unit,getPlayerUID _unit);
+    };
+}, [_unit, CBA_missionTime]] call CBA_fnc_waitUntilAndExecute;

addons/apollo/functions/fnc_handleDisconnect.sqf

@@ -0,0 +1,28 @@
+/*
+ * Author: Jonpas
+ * Handles save and corpse removal on disconnect.
+ *
+ * Arguments:
+ * 0: Unit <OBJECT>
+ * 1: ID <NUMBER> (unused)
+ * 2: UID <STRING>
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * [unit, 11, "51792927127296126"] call tac_apollo_fnc_handleDisconnect
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+params ["_unit", "", "_uid"];
+
+if (isNull _unit) exitWith {
+    ACE_LOGERROR_1("Player not saved on disconnect - null unit (UID: %1)!",getPlayerUID _player);
+};
+
+[_unit, _uid, "save"] call FUNC(playerSingletonSave);
+
+deleteVehicle _unit;

addons/apollo/functions/fnc_handleKilled.sqf

@@ -0,0 +1,36 @@
+/*
+ * Author: Jonpas
+ * Handles killed event (mark in backend for fresh inventory).
+ * Resets inventory in combination with Respawn event. UID is not valid after quick respawn in Killed event.
+ *
+ * Arguments:
+ * 0: Player <OBJECT>
+ * 1: Killer <OBJECT>
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * [player, killer] call tac_apollo_fnc_handleKilled
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+params ["_player", "_killer"];
+TRACE_1("Handle Killed",_this);
+
+private _killerUID = getPlayerUID _killer;
+
+// Try to get UID from ACE3's damage source (ace_medical uses setDamage which makes killer always objNull)
+if (_killerUID == "") then {
+    _killerUID = getPlayerUID (_player getVariable ["ace_medical_lastDamageSource", objNull]);
+
+    // No valid UID found, assume killer was AI or Self
+    if (_killerUID == "") then {
+        _killerUID = "AI/Self";
+    };
+};
+
+// Save Killed EH data for use in Respawn EH
+_player setVariable [QGVAR(killerUID), _killerUID];