Medical - Add API for fully healing a unit

addons/medical/XEH_PREP.hpp

@@ -1,5 +1,6 @@
 PREP(addDamageToUnit);
 PREP(adjustPainLevel);
 PREP(deserializeState);
+PREP(fullHeal);
 PREP(serializeState);
 PREP(setUnconscious);

addons/medical/functions/fnc_fullHeal.sqf

@@ -0,0 +1,31 @@
+#include "..\script_component.hpp"
+/*
+ * Author: DartRuffian
+ * Fully heals the patient.
+ *
+ * Arguments:
+ * 0: Patient <OBJECT>
+ * 1: Medic <OBJECT> (default: objNull)
+ * 2: Log message <BOOL> (default: true)
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * player call ace_medical_fnc_fullHeal
+ *
+ * Public: Yes
+ */
+
+params [["_patient", objNull, [objNull]], ["_medic", objNull, [objNull]], ["_logMessage", true, [true]]];
+
+if (isNull _medic) then {
+    _medic = _patient;
+};
+
+if (!alive _patient) exitWith {
+    ERROR_2("fullHeal [medic %1][patient %2] Bad parameters",_medic,_patient);
+};
+
+[_medic, _patient, _logMessage] call EFUNC(medical_treatment,fullHeal);
+nil

addons/medical_treatment/functions/fnc_fullHeal.sqf

@@ -6,6 +6,7 @@
  * Arguments:
  * 0: Medic <OBJECT>
  * 1: Patient <OBJECT>
+ * 2: Log message <BOOL> (default: true)
  *
  * Return Value:
  * None
@@ -16,8 +17,10 @@
  * Public: No
  */
 
-params ["_medic", "_patient"];
+params ["_medic", "_patient", ["_showMessage", true]];
 
-[_patient, "activity", LSTRING(Activity_fullHeal), [[_medic, false, true] call EFUNC(common,getName)]] call FUNC(addToLog);
+if (_showMessage) then {
+    [_patient, "activity", LSTRING(Activity_fullHeal), [[_medic, false, true] call EFUNC(common,getName)]] call FUNC(addToLog);
+};
 
 [QGVAR(fullHealLocal), _patient, _patient] call CBA_fnc_targetEvent;