Add python-defcon-git

archlinuxcn/python-defcon-git/PKGBUILD

@@ -0,0 +1,46 @@
+# Maintainer: taotieren <admin@taotieren.com>
+
+pkgname=python-defcon-git
+pkgver=0.10.2.r0.g2498713
+pkgrel=1
+pkgdesc='A set of UFO based objects for use in font editing applications.'
+url='https://github.com/robotools/defcon'
+license=('MIT')
+arch=(any)
+_pydeps=(fonttools
+         fs # for fonttools[ufo]
+         unicodedata2) # for fonttools[unicode]
+depends=(python
+         "${_pydeps[@]/#/python-}")
+makedepends=(python-{build,installer}
+             python-setuptools-scm
+             python-wheel
+             git)
+checkdepends=(python-pytest)
+optdepends=(python-fontpens
+            python-lxml)
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("$pkgname::git+$url.git")
+sha256sums=('SKIP')
+
+pkgver() {
+    cd "$pkgname"
+    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+    cd "$pkgname"
+    python -m build -wn
+}
+
+check() {
+    cd "$pkgname"
+    PYTHONPATH=Lib pytest Lib/defcon/test
+}
+
+package() {
+    cd "$pkgname"
+    python -m installer -d "$pkgdir" dist/*.whl
+}
+

archlinuxcn/python-defcon-git/lilac.yaml

@@ -0,0 +1,13 @@
+maintainers:
+  - github: taotieren
+
+build_prefix: extra-x86_64
+
+pre_build: vcs_update
+
+post_build_script: |
+  git_pkgbuild_commit()
+
+update_on:
+  - source: github
+    github: robotools/defcon