Feature/localcdsearch

modules/nf-core/localcdsearch/annotate/environment.yml

@@ -0,0 +1,7 @@
+---
+# yaml-language-server: $schema=https://raw.githubusercontent.com/nf-core/modules/master/modules/environment-schema.json
+channels:
+  - conda-forge
+  - bioconda
+dependencies:
+  - "bioconda::local-cd-search=0.3.0"

modules/nf-core/localcdsearch/annotate/main.nf

@@ -0,0 +1,53 @@
+process LOCALCDSEARCH_ANNOTATE {
+    tag "$meta.id"
+    label 'process_medium'
+
+    conda "${moduleDir}/environment.yml"
+    container "${ workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container ?
+        'https://community-cr-prod.seqera.io/docker/registry/v2/blobs/sha256/e1/e1ed921c933d8eeeb0db6d72ece09ec25edab9ad441c84b070acff1592af2d54/data' :
+        'biocontainers/local-cd-search:0.3.0--pyhdfd78af_0' }"
+
+    input:
+    tuple val(meta), path(fasta)
+    path db
+    val sites
+
+    output:
+    tuple val(meta), path("*_results.tsv"), emit: result
+    tuple val(meta), path("*_sites.tsv")  , emit: annot_sites, optional: true
+    tuple val("${task.process}"), val('local-cd-search'), eval("echo ${VERSION}"), topic: versions, emit: versions_localcdsearch
+
+    when:
+    task.ext.when == null || task.ext.when
+
+    script:
+    def args = task.ext.args ?: ''
+    VERSION = '0.3.0' // WARN: Version information not provided by tool on CLI. Please update this string when bumping container versions.
+    def prefix = task.ext.prefix ?: "${meta.id}"
+    def val_flag = sites ? "--sites-output ${prefix}_sites.tsv" : ''
+    def is_compressed = fasta.getExtension() == "gz"
+    def fasta_name = is_compressed ? fasta.getBaseName() : fasta
+    def uncompress_input = is_compressed ? "gzip -c -d ${fasta} > ${fasta_name}" : ''
+    """
+    $uncompress_input
+
+    local-cd-search \\
+        annotate \\
+        $args \\
+        $val_flag \\
+        --threads $task.cpus \\
+        ${fasta_name} \\
+        ${prefix}_results.tsv \\
+        ${db}
+    """
+
+    stub:
+    def args = task.ext.args ?: ''
+    VERSION = '0.3.0' // WARN: Version information not provided by tool on CLI. Please update this string when bumping container versions.
+    def prefix = task.ext.prefix ?: "${meta.id}"
+    """
+    echo $args
+    touch ${prefix}_results.tsv
+    ${sites ? "touch ${prefix}_sites.tsv" : ''}
+    """
+}

modules/nf-core/localcdsearch/annotate/meta.yml

@@ -0,0 +1,89 @@
+# yaml-language-server: $schema=https://raw.githubusercontent.com/nf-core/modules/master/modules/meta-schema.json
+name: "localcdsearch_annotate"
+description: A command-line tool for local protein domain annotation using NCBI's Conserved Domain Database (CDD)
+keywords:
+  - cdd
+  - rpsblast
+  - rpsbproc
+  - protein
+  - domain
+  - annotation
+tools:
+  - "localcdsearch":
+      description: "Protein annotation using local PSSM databases from CDD."
+      homepage: "https://github.com/apcamargo/local-cd-search"
+      documentation: "https://github.com/apcamargo/local-cd-search"
+      tool_dev_url: "https://github.com/apcamargo/local-cd-search"
+      licence: ["MIT"]
+      identifier: ""
+input:
+  - - meta:
+        type: map
+        description: |
+          Groovy Map containing sample information
+          e.g. `[ id:'sample1' ]`
+    - fasta:
+        type: file
+        description: Input fasta file containing protein queries sequences
+        pattern: "*.{fa,fasta,fa.gz,fasta.gz}"
+        ontologies:
+          - edam: "http://edamontology.org/format_1929" # FASTA
+  - db:
+      type: directory
+      description: Directory containing the metadata and databse directories
+      pattern: "*"
+  - sites:
+      type: boolean
+      description: When true an extra tsv output file is generated
+
+output:
+  result:
+    - - meta:
+          type: map
+          description: |
+            Groovy Map containing sample information
+            e.g. `[ id:'sample1' ]`
+      - "*_results.tsv":
+          type: file
+          description: tab-separated file with hits filtered by CDD's curated bit-score thresholds
+          pattern: "*_results.tsv"
+          ontologies:
+            - edam: http://edamontology.org/format_3475 # TSV
+  annot_sites:
+    - - meta:
+          type: map
+          description: |
+            Groovy Map containing sample information
+            e.g. `[ id:'sample1' ]`
+      - "*_sites.tsv":
+          type: file
+          description: If --sites-output is specified, an additional tab-separated file is created with functional site annotations
+          pattern: "*_sites.tsv"
+          ontologies:
+            - edam: http://edamontology.org/format_3475 # TSV
+  versions_localcdsearch:
+    - - "${task.process}":
+          type: string
+          description: The name of the process
+      - "local-cd-search":
+          type: string
+          description: The name of the tool
+      - "echo ${VERSION}":
+          type: eval
+          description: The expression to obtain the version of the tool
+
+topics:
+  versions:
+    - - ${task.process}:
+          type: string
+          description: The name of the process
+      - local-cd-search:
+          type: string
+          description: The name of the tool
+      - echo ${VERSION}:
+          type: eval
+          description: The expression to obtain the version of the tool
+authors:
+  - "@Ales-ibt"
+maintainers:
+  - "@Ales-ibt"

modules/nf-core/localcdsearch/annotate/tests/main.nf.test

@@ -0,0 +1,126 @@
+nextflow_process {
+
+    name "Test Process LOCALCDSEARCH_ANNOTATE"
+    script "../main.nf"
+    process "LOCALCDSEARCH_ANNOTATE"
+
+    tag "modules"
+    tag "modules_nfcore"
+    tag "localcdsearch"
+    tag "localcdsearch/annotate"
+    tag "localcdsearch/download"
+
+    setup {
+        run("LOCALCDSEARCH_DOWNLOAD") {
+            script "../../download/main.nf"
+            process {
+                """
+                input[0] = ['smart']
+                """
+            }
+        }
+    }
+
+    test("sarscov2 - smart") {
+
+        when {
+            process {
+                """
+                input[0] = [ [id:'test'], file(params.modules_testdata_base_path + 'genomics/sarscov2/genome/proteome.fasta', checkIfExists: true) ]
+                input[1] = LOCALCDSEARCH_DOWNLOAD.out.db
+                input[2] = false
+                """
+            }
+        }
+
+        then {
+            assertAll (
+                { assert process.success },
+                { assert snapshot(
+                    process.out.result,
+                    process.out.findAll { key, val -> key.startsWith("versions")}
+                ).match() }
+            )
+        }
+
+    }
+
+    test("sarscov2 - smart - stub") {
+
+        options "-stub"
+
+        when {
+            process {
+                """
+                input[0] = [ [id:'test'], file(params.modules_testdata_base_path + 'genomics/sarscov2/genome/proteome.fasta', checkIfExists: true) ]
+                input[1] = LOCALCDSEARCH_DOWNLOAD.out.db
+                input[2] = false
+                """
+            }
+        }
+
+        then {
+            assertAll(
+                { assert process.success },
+                { assert snapshot(
+                    process.out.result,
+                    process.out.findAll { key, val -> key.startsWith("versions")}
+                ).match() }
+            )
+        }
+
+    }
+
+    test("sarscov2 - smart - sites") {
+
+        when {
+            process {
+                """
+                input[0] = [ [id:'test'], file(params.modules_testdata_base_path + 'genomics/sarscov2/genome/proteome.fasta', checkIfExists: true) ]
+                input[1] = LOCALCDSEARCH_DOWNLOAD.out.db
+                input[2] = true
+                """
+            }
+        }
+
+        then {
+            assertAll(
+                { assert process.success },
+                { assert snapshot(
+                    process.out.result,
+                    process.out.annot_sites,
+                    process.out.findAll { key, val -> key.startsWith("versions")}
+                ).match() }
+            )
+        }
+
+    }
+
+    test("sarscov2 - smart - sites - stub") {
+
+        options "-stub"
+
+        when {
+            process {
+                """
+                input[0] = [ [id:'test'], file(params.modules_testdata_base_path + 'genomics/sarscov2/genome/proteome.fasta', checkIfExists: true) ]
+                input[1] = LOCALCDSEARCH_DOWNLOAD.out.db
+                input[2] = true
+                """
+            }
+        }
+
+        then {
+            assertAll(
+                { assert process.success },
+                { assert snapshot(
+                    process.out.result,
+                    process.out.annot_sites,
+                    process.out.findAll { key, val -> key.startsWith("versions")}
+                ).match() }
+            )
+        }
+
+    }
+
+}