Add nupm test

nupm/install.nu

@@ -1,27 +1,7 @@
 use std log
 
 use utils/dirs.nu [ nupm-home-prompt script-dir module-dir tmp-dir ]
-
-def throw-error [
-    error: string
-    text?: string
-    --span: record<start: int, end: int>
-] {
-    let error = $"(ansi red_bold)($error)(ansi reset)"
-
-    if $span == null {
-        error make --unspanned { msg: $error }
-    }
-
-    error make {
-        msg: $error
-        label: {
-            text: ($text | default "this caused an internal error")
-            start: $span.start
-            end: $span.end
-        }
-    }
-}
+use utils/log.nu throw-error
 
 def open-package-file [dir: path] {
     let package_file = $dir | path join "package.nuon"
@@ -64,15 +44,18 @@ def install-scripts [
 ]: list<path> -> nothing {
     each {|script|
         let src_path = $pkg_dir | path join $script
-        let tgt_path = $scripts_dir | path join $script
 
         if ($src_path | path type) != file {
             throw-error $"Script ($src_path) does not exist"
         }
 
-        if ($tgt_path | path type) == file and (not $force) {
-            throw-error ($"Script ($src_path) is already installed as"
-                + $" ($tgt_path). Use `--force` to override the package.")
+        if (($scripts_dir
+                | path join ($script | path basename)
+                | path type) == file
+            and (not $force)
+        ) {
+            throw-error ($"Script ($src_path) is already installed in"
+                + $" ($scripts_dir). Use `--force` to override the package.")
         }
 
         log debug $"installing script `($src_path)` to `($scripts_dir)`"
@@ -120,15 +103,15 @@ def install-path [
                 log debug $"installing scripts for package ($package.name)"
 
                 $package.scripts
-                | install-scripts $pkg_dir (script-dir --ensure) --force  $force
+                | install-scripts $pkg_dir (script-dir --ensure) --force $force
             }
         },
         "script" => {
             log debug $"installing scripts for package ($package.name)"
 
-            $package.scripts?
-            | default [ ($pkg_dir | path join $"($package.name).nu") ]
-            | install-scripts $pkg_dir (script-dir --ensure) --force  $force
+            [ ($pkg_dir | path join $"($package.name).nu") ]
+            | append ($package.scripts? | default [])
+            | install-scripts $pkg_dir (script-dir --ensure) --force $force
         },
         "custom" => {
             let build_file = $pkg_dir | path join "build.nu"

nupm/test.nu

@@ -0,0 +1,80 @@
+use utils/dirs.nu [ tmp-dir find-root ]
+use utils/log.nu throw-error
+
+# Experimental test runner
+export def main [
+    filter?: string  = ''  # Run only tests containing this substring
+    --dir: path  # Directory where to run tests (default: $env.PWD)
+    --show-stdout  # Show standard output of each test
+]: nothing -> nothing {
+    let dir = ($dir | default $env.PWD | path expand -s)
+    let pkg_root = find-root $dir
+
+    if $pkg_root == null {
+        throw-error ($'Could not find "package.nuon" in ($dir)'
+            + ' or any parent directory.')
+    }
+
+    print $'Testing package ($pkg_root)'
+    cd $pkg_root
+
+    let tests = nu [
+        --no-config-file
+        --commands
+        'use tests/
+
+        scope commands
+        | where ($it.name | str starts-with tests)
+        | get name
+        | to nuon'
+    ]
+    | from nuon
+
+    let out = $tests
+        | where ($filter in $it)
+        | par-each {|test|
+            let res = do {
+                nu [
+                    --no-config-file
+                    --commands
+                    $'use tests/; ($test)'
+                ]
+            }
+            | complete
+
+            if $res.exit_code == 0 {
+                print $'($test) ... (ansi gb)SUCCESS(ansi reset)'
+            } else {
+                print $'($test) ... (ansi rb)FAILURE(ansi reset)'
+            }
+
+            if $show_stdout {
+                print 'stdout:'
+                print $res.stdout
+            }
+
+            {
+                name: $test
+                stdout: $res.stdout
+                stderr: $res.stderr
+                exit_code: $res.exit_code
+            }
+        }
+
+    let successes = $out | where exit_code == 0
+    let failures = $out | where exit_code != 0
+
+    $failures | each {|fail|
+        print ($'(char nl)Test "($fail.name)" failed with exit code'
+            + $' ($fail.exit_code):(char nl)'
+            + ($fail.stderr | str trim))
+    }
+
+    if ($failures | length) != 0 {
+        print ''
+    }
+
+    print ($'Ran ($out | length) tests.'
+        + $' ($successes | length) succeeded,'
+        + $' ($failures | length) failed.')
+}

nupm/utils/dirs.nu

@@ -72,3 +72,24 @@ export def tmp-dir [subdir: string, --ensure]: nothing -> path {
 
     $d
 }
+
+# Try to find the package root directory by looking for package.nuon in parent
+# directories.
+export def find-root [dir: path]: [ nothing -> path, nothing -> nothing] {
+    let root_candidate = 1..($dir | path split | length)
+        | reduce -f $dir {|_, acc|
+            if ($acc | path join package.nuon | path exists) {
+                $acc
+            } else {
+                $acc | path dirname
+            }
+        }
+
+    # We need to do the last check in case the reduce loop ran to the end
+    # without finding package.nuon
+    if ($root_candidate | path join package.nuon | path type) == 'file' {
+        $root_candidate
+    } else {
+        null
+    }
+}

nupm/utils/log.nu

@@ -0,0 +1,21 @@
+
+export def throw-error [
+    error: string
+    text?: string
+    --span: record<start: int, end: int>
+] {
+    let error = $"(ansi red_bold)($error)(ansi reset)"
+
+    if $span == null {
+        error make --unspanned { msg: $error }
+    }
+
+    error make {
+        msg: $error
+        label: {
+            text: ($text | default "this caused an internal error")
+            start: $span.start
+            end: $span.end
+        }
+    }
+}

package.nuon

@@ -0,0 +1,7 @@
+{
+    name: nupm
+    type: module
+    version: "0.1.0"
+    description: "Nushell package manager"
+    license: "LICENSE"
+}

tests/mod.nu

@@ -0,0 +1,49 @@
+use std assert
+
+use ../nupm/utils/dirs.nu tmp-dir
+use ../nupm
+
+
+def with-nupm-home [closure: closure]: nothing -> nothing {
+    let dir = tmp-dir test --ensure
+    with-env { NUPM_HOME: $dir } $closure
+    rm -r $dir
+}
+
+export def install-script [] {
+    with-nupm-home {
+        cd tests/packages/spam_script
+
+        nupm install --path .
+        assert ([$env.NUPM_HOME scripts spam_script.nu]
+            | path join
+            | path exists)
+        assert ([$env.NUPM_HOME scripts spam_bar.nu]
+            | path join
+            | path exists)
+    }
+}
+
+export def install-module [] {
+    with-nupm-home {
+        cd tests/packages/spam_module
+
+        nupm install --path .
+        assert ([$env.NUPM_HOME scripts script.nu] | path join | path exists)
+        assert ([$env.NUPM_HOME modules spam_module] | path join | path exists)
+        assert ([$env.NUPM_HOME modules spam_module mod.nu]
+            | path join
+            | path exists)
+    }
+}
+
+export def install-custom [] {
+    with-nupm-home {
+        cd tests/packages/spam_custom
+
+        nupm install --path .
+        assert ([$env.NUPM_HOME plugins nu_plugin_test]
+            | path join
+            | path exists)
+    }
+}

tests/packages/spam_custom/build.nu

@@ -0,0 +1,6 @@
+def main [package_file: path] {
+    let package = open $package_file
+    print $"Installing ($package.name) to ($env.NUPM_HOME) inside ($env.PWD)"
+    mkdir ($env.NUPM_HOME | path join plugins)
+    touch ($env.NUPM_HOME | path join plugins nu_plugin_test)
+}

tests/packages/spam_custom/package.nuon

@@ -0,0 +1,5 @@
+{
+    name: spam_custom,
+    type: custom,
+    version: "0.1.0"
+}

tests/packages/spam_module/package.nuon

@@ -0,0 +1,6 @@
+{
+    name: spam_module,
+    type: module,
+    version: "0.1.0"
+    scripts: script.nu
+}

tests/packages/spam_module/script.nu

@@ -0,0 +1 @@
+print 'scriptscript'

tests/packages/spam_module/spam_module/mod.nu

@@ -0,0 +1,3 @@
+export def main [] {
+    "Hello world!"
+}

tests/packages/spam_script/package.nuon

@@ -0,0 +1,6 @@
+{
+    name: spam_script,
+    type: script,
+    version: "0.1.0",
+    scripts: ['spam_bar.nu']
+}

tests/packages/spam_script/spam_bar.nu

@@ -0,0 +1,3 @@
+export def main [] {
+    'Hello bar!'
+}

tests/packages/spam_script/spam_script.nu

@@ -0,0 +1,4 @@
+#!/usr/bin/env nu
+def main [] {
+    "Hello world!"
+}