hackman

[kostmo]

Demo

scripts/play.sh --scenario Challenges/hackman.yaml --autoplay

Makes use of both #1058 and #1023.

[byorgey]

Nice! I wrote some code to follow and eat pellets + donuts as long as there are any adjacent. But I had to manually move hackman between each string of pellets once it ate a bunch and ended up next to blank spaces. I'm still wondering if there is a less manual way to do it. What about equipping hackman with a bitcoin? Then at the very least you could code it to wander around randomly until encountering more things to eat.

Once we do #102 it could also be fun to equip hackman with whatever device lets you handle input. Then one strategy would be to code up your own key handler so you could actually e.g. drive hackman around with arrow keys.

[byorgey]

I'm proud of this solution I developed, which eventually manages to eat everything (though it takes a while):

def ifC : cmd bool -> {cmd a} -> {cmd a} -> cmd a = \test. \then. \else.
  b <- test; if b then else
end

def while : cmd bool -> {cmd a} -> cmd unit = \test. \body.
  ifC test {force body ; while test body} {}
end

def unless = \test. \then. \else. ifC test else then end

def until = \test. \body.
  ifC test {} {force body ; until test body}
end

def elsif = \p. \then. \else. {if p then else} end
def elsifC = \p. \then. \else. {ifC p then else} end

def forever : cmd a -> cmd b = \c.
  c; forever c
end

def inverseDir : dir -> dir = \d.
  if (d == left) {right} {if (d == right) {left} {d}}
end

def isBlocked : dir -> cmd bool = \d.
  turn d;
  b <- blocked;
  turn (inverseDir d);
  return b
end

def followLeft =
  unless (isBlocked left) {turn left}
  { unless (isBlocked forward) {}
    { unless (isBlocked right) {turn right} {turn back} } };
  move
end

def followRight =
  unless (isBlocked right) {turn right}
  { unless (isBlocked forward) {}
    { unless (isBlocked left) {turn left} {turn back} } };
  move
end

def isFood = \x. x == inr "pellet" || x == inr "donut" end

def isFoodTo = \d. res <- scan d; return (isFood res) end

def stepToFood =
  ifC (isFoodTo left) {turn left; move}
  $ elsifC (isFoodTo forward) {move}
  $ elsifC (isFoodTo right) {turn right; move}
  $ elsifC (isFoodTo back) {turn back; move} {}
end

def followFood = while (isFoodTo down) { grab; stepToFood } end

def eatAll =
  forever (
    until (isFoodTo down) { followRight; followLeft; followLeft; stepToFood };
    followFood
  )
end