How to make aspect configurable?

[blemouzy]

Hello,

I'm trying to make my user aspect configurable from an host option called hasGui:

{
  den.hosts.x86_64-linux = {
    nixos-vm = {
      hasGui = true;
      users = {
        benjamin = { };
      };
    };
  };
}

{ __findFile, ... }:
let
  gui-includes = [
    <ble/apps/gui>
  ];
  no-gui-includes = [
    <ble/apps/cli>
  ];
in
{
  den.aspects.benjamin._.gui =
    { host, ... }:
    if (host.hasGui or true) then { includes = gui-includes; } else { includes = no-gui-includes; };

  den.aspects.benjamin = {
    includes = [
      <den.aspects.benjamin/gui>
    ];
  };
}

Files are syntactical correct but gui applications are not included...

I read the https://den.oeiuwq.com/context-aware.html documentation page but I don't understand it...

Can someone help me to fix my code or give me link to a working example?

[vic]

hi, this is a bug (#145) where parametric aspects are not included for user. I hope to be working on it today.

[blemouzy]

hi, this is a bug (#145) where parametric aspects are not included for user. I hope to be working on it today.

Thanks for the reply: I was starting to go crazy trying to get it to work!

[vic]

Merged now at #148,

I was starting to go crazy trying to get it to work!

don't know why we did not have a test for checking user parametric includes. We do now. :)

Btw

<den.aspects.benjamin/gui> is just <benhamin/gui>

See angle bracket doc

[blemouzy]

Thanks for the fix.

Still doesn't work for me with the following code:

{ __findFile, den, ... }:
let
  cli-includes = [
    <ble/apps/cli>
  ];
  gui-includes = [
    <ble/apps/gui>
  ];
  user-includes =
    { host, ... }:
    {
      includes = cli-includes ++ (if (host.hasGui or true) then gui-includes else [ ]);
    };
in
{
  den.aspects.benjamin = {
    includes = [ user-includes ];

   ...
};

I got a error: attribute 'includes' missing error.

It is the right way to test host option?

[vic]

that's the correct way to test the host option. the error includes missing is something else, I'll need to test your particular example.

[vic]

Tested with this:

{
  inputs,
  den,
  lib,
  ...
}:
let
  base.homeManager.temp = [ "base" ];
  warm.homeManager.temp = [ "warm" ];
  cold.homeManager.temp = [ "cold" ];

  tux-includes = { host, ... }: {
    includes = [ base ] ++ (if host.isWarm then [ warm ] else [ cold ]);
  };
in
{
  den.hosts.x86_64-linux.igloo.users.tux = { };
  den.hosts.x86_64-linux.igloo.isWarm = true;

  den.aspects.tux.includes = [ tux-includes ];
  den.aspects.tux.homeManager.options.temp = lib.mkOption { type = lib.types.listOf lib.types.str; };

  flake.tests.testItWorks =
    let
      igloo = inputs.self.nixosConfigurations.igloo.config;
      tux = igloo.home-manager.users.tux;

      expr = tux.temp;
      expected = [ "warm" "base" ];
    in
    {
      inherit expr expected;
    };
}

and it worked as expected, my temp homeManager option gets "warm" because igloo.isWarm = true;

[vic]

maybe there's something else that is not visible in your code that is causing the includes error, can you please create a reproduction repo ? (based of the bogus template?)

try keeping it minimal just enough to reproduce the includes error, please.

[blemouzy]

So I made a minimal example and it works (https://github.com/blemouzy/den-bug, working branch):

{
  den.aspects.apps._.a.homeManager =
    { pkgs, ... }:
    {
      home.packages = [ pkgs.cowsay ];
    };
}

---

{
  den.aspects.apps._.b.homeManager =
    { pkgs, ... }:
    {
      home.packages = [ pkgs.hello ];
    };
}

---

{ __findFile, den, ... }:
let
  a-includes = [
    <apps/a>
  ];
  b-includes = [
    <apps/b>
  ];
  user-includes =
    { host, ... }:
    {
      includes = a-includes ++ (if (host.isWarm or true) then b-includes else [ ]);
    };
in
{
  den.aspects.tux = {
    includes = [ user-includes ];
  };
}

I check the following command output to see the result:

sudo nixos-rebuild dry-build --flake .#igloo 2>&1 | grep -E "cowsay|hello"

So now, I'm trying to add my stuff, piece by piece, to found the error.

With the following code (https://github.com/blemouzy/den-bug, non-working-input branch):

  den.default.includes = [
    den.provides.inputs'
  ];

  den.aspects.apps._.a.homeManager =
    { inputs', ... }:
    {
      home.packages = [ inputs'.nixpkgs-unstable.legacyPackages.cowsay ];
    };

I got the following error:

    error: The option `home-manager.users.tux._module.args.inputs'' is defined multiple times while it's expected to be unique.

    Definition values:
    - In `/nix/store/b79a4h16k59h5hxq696xfsvspk4av19g-source/modules/aspects/provides/inputs.nix, via option den.provides.inputs'.<function body>.includes."[definition 1-entry 1]".homeManager'
    - In `/nix/store/b79a4h16k59h5hxq696xfsvspk4av19g-source/modules/aspects/provides/inputs.nix, via option den.provides.inputs'.<function body>.includes."[definition 1-entry 1]".homeManager'

With the following code (https://github.com/blemouzy/den-bug, non-working-unfree branch):

{ den, ... }:
{
  den.aspects.apps._.a = {
    includes = [
      (den._.unfree [
        "vscode"
      ])
    ];

    homeManager =
      { pkgs, ... }:
      {
        home.packages = [ pkgs.vscode ];
      };
  };
}

I got the following error:

       error: The option `home-manager.users.tux.unfree.packages' in `/nix/store/b79a4h16k59h5hxq696xfsvspk4av19g-source/modules/aspects/provides/unfree/unfree-predicate-builder.nix, via option den.default.includes."[definition 1-entry 1]".<function body>.includes."[definition 1-entry 1]".homeManager' is already declared in `/nix/store/b79a4h16k59h5hxq696xfsvspk4av19g-source/modules/aspects/provides/unfree/unfree-predicate-builder.nix, via option den.default.includes."[definition 1-entry 1]".<function body>.includes."[definition 1-entry 1]".homeManager'.
Command 'nix --extra-experimental-features 'nix-command flakes' build --print-out-paths '.#nixosConfigurations."igloo".config.system.build.toplevel' --dry-run' returned non-zero exit status 1.

Apart from these errors, I think my original issue came from the fact that my aspects were in a personal namespace and not in "den.aspects."
I'll retest that once the other errors are fixed.

EDIT : issues reported in #150

[vic]

Thanks a lot for your reproduction repo, it was very helpful. I've added tests based on your code and fixed the bug at #153

[blemouzy]

Everything works fine now (inputs' and unfree issues are solved).

Thanks!